set rs=conn.execute,set rs=server.createobject(“ADODB.recordset”)的性能对比

(编辑：jimmy 日期: 2024/11/14 浏览：3 次 )

经常用asp的同行，可能会建议用set rs=conn.execute(sql)来代替set rs=server.createobject(“ADODB.recordset”):rs.open conn,sql,1,1。还有一些同行更提出了用set rs=conn.execute(sql):res=rs.getRows(100)来优化ASP程序。其实在没有做此实验前，我也是很相信这种方法的。实际效果果真如此吗？经过一番测试，我发现结果远非如此，set rs=server.createobject(“ADODB.recordset”)的方法比set rs=conn.execute的方法快4~5倍。这个结果您信吗？不信，更我来一起做这个测试。

数据说明真相。首先创建一个多记录的数据库。

set conn=createobject("adodb.connection")
conn.open "provider=microsoft.jet.oledb.4.0;data source=E:\labs\miaoqiyuan.cn\g.mdb"
do while conn.execute("select count(id) from site")(0)<1000000
	conn.execute("insert into site(sitename,siteadmin,siteurl,sitekey) values('苗启源','http://localhost/app_login/','http://www.miaoqiyuan.cn','e10adc3949ba59abbe56e057f20f883e')")
loop

经过几个小时的运行，我得到了一个有63万多条记录的数据库。数据库大小为99.7MB(测试数据库下载地址rs-execute-test.rar)。

为了保证数据的真实性，我们用公共的头部header.asp来保存数据库连接字符串。footer.asp来保存运行时间。

运行环境，Windows 2003 Server SP2。IIS6.0，CPU E2200 2.2GHz，内存2Gx2。硬盘300G SATA+80G ATA。

公共头部:header.asp

<%
startTme=timer()
set conn=server.createobject("ADODB.connection")
conn.open "provider=microsoft.jet.oledb.4.0;data source="&server.mappath("g.mdb")
%>

公共底部:footer.asp

<hr />总共用时：< %=(timer()-startTme)*1000%>毫秒

测试方法：以三种方式，每页100条记录。同时读取第6000页到6099页的记录共一万条，并测出运行时间。

test1.asp，采用set rs=server.createobject(“ADODB.recordset”)的方法。

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.pagesize=100
	rs.absolutepage=6000+k
	i=0
	do while not rs.eof and i<100
		i=i+1
		response.write rs("id")&":"&rs("sitename")&"<br />"&vbCrlf
		rs.movenext
	loop
	rs.close
	set rs=nothing

next
%>

test2.asp 采用set rs=conn.execute()的方法

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=conn.execute("select * from site")
	rs.movefirst
	rs.move (6000+k)*100
	i=0
	do while not rs.eof and i<100
		i=i+1
		response.write rs("id")&":"&rs("sitename")&"<br />"&vbCrlf
		rs.movenext
	loop
	rs.close
	set rs=nothing

next
%>

至于getRows，这种方法只能算是返回结果的优化，并不能算是一种方法。我们采用两种返回结果的方式测试。test3.asp采用set rs=server.createobject(“ADODB.recordset”)的方法,test4.asp采用set rs=conn.execute(sql)的方法

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.pagesize=100
	rs.absolutepage=6000+k
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=conn.execute("select * from site")
	rs.movefirst
	rs.move (6000+k)*100
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>

下面是我的测试结果：

文件名 test1.asp test2.asp test3.asp test4.asp 第一次测试 4281.25毫秒 20656.25毫秒 4281.25毫秒 18671.88毫秒第二次测试 4234.375毫秒 25171.88毫秒 4312.5毫秒 13781.25毫秒第三次测试 4328.125毫秒 20031.25毫秒 4234.375毫秒 19093.75毫秒

为什么会出现这种结果呢？set rs=conn.execute(sql),set rs=server.createobject(“ADODB.recordset”)为什么为相差这么多？对比一下test1.asp、test3.asp与test2.asp、test4.asp，除了返回结果的方式不同，还有一处就是rs.move。难道是这个原因？把test3.asp的代码稍微修改一下。存为test5.asp。

< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.movefirst
	rs.move (6000+k)*100
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>

经过测试，test5.asp能比test3.asp快0.1~0.2秒，如果读取100条数据，这点差距可以忽略不计。

由此可见：set rs=conn.execute的方式确实比set rs=server.createobject(“ADODB.recordset”)方式慢，在学校的时候，老师教的一般都是set rs=server.createobject(“ADODB.recordset”)的方法，真正工作室，学习所谓的高手set rs=conn.execute优化的方法，结果最终发现，而鄙视用老师教的方法写程序的同行，最终发现还是老师教的速度快，而且set rs=server.createobject(“ADODB.recordset”)的方法比set rs=conn.execute的方法快4~5倍。囧。。。。

难道set rs=conn.execute就一无是处了吗？在数据插入方面，两者的差别有多大呢？

下面是其他网友的补充

没有可比性，为什么非要比呢？
set rs=conn.execute()
rs.getrows()
这种方法一般用在数据量少的情况下，比如说只有几十几百条数据的情况下，它只读一次数据库，然后把结果存入一个二维数组中，在这之后的操作就不需要数据库，而是直接对内存中的数据进行操作了，速度绝对比用常规方法快，而且也节省资源。而用常规方法的话，数据库操作得多少次？而在日常的情况下，一次读取大量数据的情况是很少的，所以在很多地方都提到使用上面这种方法，就是缘于此。
还有上面比的分页，常规方法由于它自身的局限，对数据库的操作很费资源的，别说只是快那零点几秒，好的程序到最后拼的就是那零点几秒。

rs.open sql,conn 与conn.execute(sql)的区别

什么时候用什么"select * from admin where username='xiaozhu'"
set rs=conn.execute(sql)
'执行完以后自动关闭记录集
'最后只需要关闭连接就可以了
conn.close
set conn=nothing

2.rs.open

set rs=server.createobject("adodb.recordset")
sql="select * from admin where username='xiaozhu'"
rs.open sql,conn,1,1
'可以自己设定一些参数，即锁定和游标的移动方式
'最后要关闭记录集和连接
rs.close
set rs=nothing
conn.close
set conn=nothing

3.command.execute

sql="select * from admin where username='xiaozhu'"
set rs=command.execute(sql)

1.
set rs=conn.execute("如果是select语句") 得到的rs.recordcount=-1
rs.open sql,conn("sql为select语句") 得到的rs.recordcount为正常的记录数

2.
rs.open是打开数据库 conn.execute 是执行SQL指令
set rs=conn.execute(insert,update,delete)返回一个关闭了的记录集
set rs=conn.execute(select)返回一个没有关闭的记录集

3.
CONN.EXECUTE(SQL,RowsAffected,C)

参数含义:

SQL的值可以是SQL语句、表名、存储过程名，也可以是数据提供者所能接受的任意字符串。为了提高性能，最好为C参数指定合适的值

可选参数RowsAffected将返回INSERT、UPDATE或DELETE查询执行以后所影响的数目。这些查询会返回一个关闭的Recordset对象。

一个SELECT查询将返回RowsAffected值为-1并且返回带有一行或多行内容的打开的Recordset。

4.
conn.execute sql适合于不需返回recordset对象时使用，比如下面的代码：
sql="delete from enews where id="&cstr(id)
conn.execute sql

如果需要返回recordset对象，则使用如下代码：
sql="select from enews where id="&cstr(id)
set rs = conn.execute(sql)

如果去掉execute(sql)这儿的括号(即为set rs = conn.execute sql)，就会提示“语句未结束”这样的错误提示，我翻看了一下语法格式，发现有二种格式，详解如下：

格式一：Connection对象名.Execute(SQL指令).
格式二：Connection对象名.Execute(数据表名)。
附：

set rs = conn.execute(sql)

是带有返回值的，一般sql为查询的时候使用。如
set rs = conn.execute("select * from ...")
当然执行insert into 和delete也是可以的
set rs = conn.execute("insert into table (f1,f2..")
但是要创建Recordset对象，占用服务器资源。在insert into, delete的时候我们一般不需要返回记录集。所以我是这样认为的：

在使用查询的时候，用 set rs = conn.execute("select * from table")
在插入和删除时候，用 conn.execute("delete from table where ...")

第二种方式代码简洁，不需要显式地创建Recordset对象(但实际上好象是隐式创建的)

第二种方法还有一些简洁的写法：如，最某表的记录数

dim count
count = conn.execute(select count(*) from table)(0)
上面的语句等于
count = conn.execute(select count(*) from table).fields(0).value

综上：区别在于set rs = conn.execute是显示创建recordset对象，而conn.execute是隐式的。
能用conn.execute的时候就用conn.execute，好处有
一、代码简洁
二、效率应该有所提高

再摘引一下：（srnld（天涯））

形成记录集的方法有三种 CONN.execute   rs.open   Command.execute
方法用法大大不通

通常 Set rs=CONN.execute(SQL)
或直接 rs=CONN.execute(SQL)

和   Set rs=Server.CreateObject("ADODB.Recordset")
    rs.open SQL,CONN,0,1   或 rs.open SQL,CONN
这种情况通常open比上一个性能要好那么一丁点
(   command对象更灵活,执行范围更广)

使用 CONN.execute 可以不用关闭直接执行下一个 set rs=conn.execute(SQL)
但性能速度会大打折扣!!
大约要慢 2~5倍!!(这是我在msSQL循环1000次亲自测试过的,不信你马上自己测试),所以执行下一个 rs=conn.execute之前!!一定要关闭掉!是个好习惯!
使用单一对象的rs   rs.open在open下一个记录集之前,必需要求显示关闭,否则出错,速度在SQL,CONN,0,1的情况下可前者基本一样

所以我喜欢使用直设置一个 CreateObject("adodb.recordser")(在不需要多个记录集交错操作的情况下,多个也不碍是!)
然后从头用到尾!!!
开门关门开门关门~~~~~咵踏咵踏~~~~
最后一个 set rs=nothing 化上句号,爽!

更主要是 open提供非常灵活的操作数据库元数据的非常多的属性!!
打开百宝箱,金光灿灿什么都看见!
有很多情况下是非得用open来做的!
而conn.execute 想黑布下换胶卷~~~偷偷摸摸~~非常单一!!!

比如:

rs1.open SQL1,conn,0,1
rs.open SQL,conn,1,3
if rs(0)<0 then rs(0)=0
rs(1)=aaa
rs(2)=bbb
rs.update ' 更新记录集写到数据库

rs.addnew '加一条新记录
rs(0)=1
rs(1)=ddd
rs(2)=kkk
rs.update
id=rs(3)   rs(s) '取的字段是自动编号立即获得新记录的自动编号id //这是非常常用的

rs1.addnew 对rs1添加关连使用id rs的新记录
rs1("id")=id
rs1(1)=...
..
rs1.update

rs1.close:set rs1=nothing
rs.close:set rs=nothing

上面的操作如果采用CONN.execute 则要用到四个 CONN.execute

CONN.execute("update ..")
CONN.execute("insert into 表1:")
rs=CONN.execute("select 新的自动 id")
CONN.execute("insert into 表二")
那一种方法逻辑条理更好~~一目了然

======================

还有一个有趣的使用Recordset open记录的方法!!
我想起来是有点费解

Set rs=server.CreateObject("Adodb.recordset")
Set rs=server.CreateObject("Adodb.recordset")

rs.open SQL1,CONN
rs.open SQL2,CONN

'嘿嘿~~~这是同时设置同名的两个对象来打开两个记录集,而且是可用的!
'只要取的列名合乎这两个记录集中元数据
'则正常操作!!
扩展开来

Set rs=server.CreateObject("Adodb.recordset")
Set rs=server.CreateObject("Adodb.recordset")
Set rs=server.CreateObject("Adodb.recordset")
Set rs=server.CreateObject("Adodb.recordset")

rs.open SQL1,CONN
rs.open SQL2,CONN
rs.open SQL3,CONN
rs.open SQL4,CONN

这样大于二个同名的 rs我还没试过!!

感觉有点相当与 SQL联合查询再打开记录集~~~
以前我这样用过!!应该不是眼花!!

上一篇：ASP中RecordSet Open和Connection.Execute一些区别与细节分享
下一篇：完美的ASP分页脚本代码